;Z8 ASSEMBLER DI IK1WJQ, TIME.ASM, QUARZO 8 MHZ
    ;PROGRAMMA TEMPORIZZATORE 0,5 - 4 SEC
    ;RIPETITORE DI SEGNALE CON RILASCIO RITARDATO
    ;PORTE: P20 - P23 INGRESSI PROGRAMMAZIONE TEMPO
    ;P31 INGRESSO SEGNALE - USCITE P00 LED - P01,P02  AL TX
  
            TEMP EQU R5           ;DATO TEMPORANEO
            DATO EQU R6           ;DATO CARICATO
            
            ORG    000CH

                   LD P01M,#4     ;P0 USCENTE
                   LD RP,#0       ;R0-R3 COME PORTE
                   CLR R0         
                   LD SPL,#127
                   LD P3M,#1      ;P3 INGRESSO DIGITALE
                   LD P2M,#15     ;P2 INGRESSI P20-P23
                   CALL MEZ
                   CALL LEDX      ;DUE COLPI LED
                   CALL LEDX      
                   TM R2,#1       ;CONTROLLO TEMPO IMPOSTATO
                   JR Z,UNO
                   TM R2,#2
                   JR Z,DUE
                   TM R2,#4
                   JR Z,TRE
                   TM R2,#8
                   JR Z,QUA
                   LD TEMP,#1     ;0,5 SEC
                   JR INI
            UNO:   LD TEMP,#2     ;1 SEC
                   JR INI
            DUE:   LD TEMP,#4     ;2 SEC
                   JR INI
            TRE:   LD TEMP,#6     ;3 SEC
                   JR INI
            QUA:   LD TEMP,#8     ;4 SEC
                   JR INI
            CONX:  LD R0,#6       ;PO1, P02 = 1 LED = 0
             INI:  TM R3,#2       ;CONTROLLO SEGNALE P31
                   JR NZ,CONX     ;ASP. SEGNALE -> 0 VOLT
            CONT:  LD R0,#1       ;USCITE A ZERO LED = 1
                   TM R3,#2       ;TX ATTIVO
                   JR Z,CONT      ;CONTROLLO SUCESSIVO
                   LD DATO,TEMP   ;AGGIUNTA RITARDO
              TR:  CALL MEZ       ;CHIAMA 0,5 SEC
                   DJNZ DATO,TR   ;TEMP - 1
                   JR CONX

            LEDX:  OR R0,#1       ;COLPO DI LED
                   CALL MEZ       ;0,5 SEC
                   AND R0,#6      ;P01 E P02 INVARIATI
                   CALL MEZ
                   RET

             MEZ:  LD R15,#163    ;0,5 SEC RITARDO
                   JR RIT1

            RIT:   LD R15,#0      ;RIT. 0,786 SEC. 
            RIT1:  LD R14,#0
            RIT2:  NOP
                   NOP
                   DJNZ R14,RIT2
            RIT3:  NOP
                   NOP
                   DJNZ R14,RIT3
                   DJNZ R15,RIT1
                   RET
                   
                   END

Schema base


Foto, montaggio dispositivo con 7805 per alimentazione a 12 Volt 


Vai a pagina1