Olivetti M10 e Tandy 102 in telegrafia FM alle massime velocità
Icom T8E - V/UHF tre bande om
I piccoli rtx portatili o tascabili in FM, come in questo caso l'ICOM T8E, non hanno
l'ascolto in AM e tantomeno la CW o l'SSB, tuttavia sulle bande VHF-UHF e oltre,
è facile poter fare la telegrafia modulata, visto l'ampio spazio a disposizione su
queste bande, e la mancanza di qrm per qso alla distanza di alcuni chilometri .
(Un canale in FM banda stretta, occupa circa 12,5 Khz).
Ecco allora un'applicazione con i vecchi e noti computer Olivetti M10 o il corrispondente
americano Tandy 102.
NOTA: Con i piccoli Rtx muniti di vox, non serve l'interfaccia, ma basta posizionare
un microfono volante vicino al diffusore piezoelettrico del pc.
In questo modo il segnale audio è sufficiente ad attivare la trasmissione automatica.
Il programma iniziale serve a trasmettere un messaggio, che viene ripetuto dopo un certo
tempo, il secondo invece permette di usare una chiave a due palette per fare la telegrafia
in FM o AM, usando sempre l'uscita audio del pc.
La risposta del programma è buona, per cui oltre agli esperti se si è alle prime armi, lo
si può usare anche per imparare la manipolazione con la chiave meccanica.
I programmi sono funzionanti al 100%, ma naturalmente si possono ampliare, l'importante
è non rallentare l'esecuzione nella fase di decodifica e trasmissione.
Per semplificare l'esecuzione automatica si decodifica solo i numeri e le lettere oltre
allo spazio tra le varie parole.
Semplice schema dell'interfaccia per la telegrafia in FM con l'ICOM T8E
Audio <-------||-----\/\/\/-----*------------------------------------> Ingresso
2nF 200K | Jack da 2,5 mm mono microfono IC
\ *---------------------> T8E con PTT.
M10 o Tandy 102 / |
\ 2K2 /////
|
(PTT) |
4K7 (C) BC238
DTR (20)<---\/\/\/--*-------*----(B)
| | (E) (*): L'interruttore (bistabile) si usa
RS Chiuso=RX | 4 _|_ | solo per la telegrafia manuale, in
232 \ 1 / \ | modo da commutare velocemente in
Aperto=TX \ 4 | | ricezione senza dover usare i tasti
(*) * 8 | | del computer, che in questo caso si
| | | usa principalmente con la chiave
GND (7)<-----------*-------*-----* meccanica come un tasto automatico
| tradizionale. (Programma da riga 400)
/////
Il seguente programma gira ad elevata velocità, perché usa solo i numeri interi.
Con i valori qui riportati e con il quarzo da 6 Mhz anzichè l'originale da 4,9152 Mhz,
la velocità di trasmissione è di circa 44 PM ossia 44 x 5 = 220 caratteri al minuto,
e si capisce che riducendo i cicli (FOR-NEXT) si può arrivare tranquillamente anche a
60 PM e oltre.
Per ridurre radicalmente la velocità basta eliminare dal programma la riga 0
0 DEFINT A-Z'NUMERI INTERI=BASIC VELOCE
5 OUT 178,236
10 PRINT "CONTROLLO TX ICOM T8E
15 U=178'INDIRIZZO PORTA RS232
20 TX=232-64'COMANDO TRASMISSIONE FM (DTR=1)
25 RX=236'COMANDO RICEZIONE
30 OUT U,RX
35 PRINT"PROVA TRASMISSIONE
40 OUT U,TX
45 FOR G=1 TO 60: NEXT
50 OUT U,RX
55 DIM K$(26)'DATI LETTERE
60 DIM T$(10)'DATI NUMERI
100 DATA ".-","-...","-.-.","-..",".","..-.","--.","....","..",".---","-.-",".-..","--",
"--","-.","---",".--.","--.-",".-.","...","-","..-","...-",".--","-..-","-.--","--.."
105 DATA "-----",".----","..---","...--","....-",".....","-....","--...","---..","----."
110 RESTORE: FOR F=1 TO 26: READ K$(F): NEXT
115 RESTORE 105: FOR F=0 TO 9: READ T$(F): NEXT
120 INPUT D$: IF D$="" THEN 400'SALTA AL TASTO AUTOMATICO
130 FOR W=1 TO 120
135 FOR G=1 TO 100: NEXT G: NEXT W'PAUSA 14 SECONDI CA
140 OUT U,TX+4: FOR G=1 TO 50: NEXT'ATTIVA TRASMISSIONE ICOM
145 PRINT D$
150 FOR D=1 TO LEN(D$)
153 H$=MID$(D$,D,1): IF H$=" " THEN D=D+1: FOR G=1 TO 120:NEXT G:GOTO153
155 K=ASC(H$):IF K>60 THEN 170
160 K=K-48:N$=T$(K): FOR F=1 TO LEN(N$)'ESTRAZIONE E TRASMISSIONE DEL NUMERO
164 IF MID$(N$,F,1)="." THEN GOSUB 300
166 IF MID$(N$,F,1)="-" THEN GOSUB 350
168 GOTO 190
170 K=K-64:N$=K$(K): FOR F=1 TO LEN(N$)'ESTRAZIONE E TRASMISSIONE DELLA LETTERA
175 IF MID$(N$,F,1)="." THEN GOSUB 300
180 IF MID$(N$,F,1)="-" THEN GOSUB 350
190 NEXT F: FOR G=1 TO 90: NEXT G
200 NEXT D: OUT U,RX: GOTO 130'RITORNA A TRASMETTERE IL MESSAGGIO D$
300 OUT U,168: FOR G=1 TO 30: NEXT: OUT U,172: FOR G=1 TO 30: NEXT: RETURN'PUNTO
350 OUT U,168: FOR G=1 TO 90: NEXT: OUT U,172: FOR G=1 TO 30: NEXT: RETURN'LINEA
Collegamenti per il tasto automatico
(Per attivare d5 e d6 vedi l'articolo sul Bus I2C)
Porta 9 pin BCR (M10 - Tandy 102)
Indirizzo=(208)
4n7
*--||---(0 Volt)
| (Linea) ____
D6 (3)<-----*--------------*---------/____|
|
0-Volt (5)<--------------------*----* Manipolatore con chiave a due palette - (Iambic)
| ____
D5 (4)<-----*--------------*---------\____|
| 4n7 (Punto)
*--||---(0 Volt)
400 L=208'INDIRIZZO LETTURA PORTA 9 PIN
405 PRINT"TELEGRAFIA CON CHIAVE IAMBIC IN FM
407 V=INP(L): IF V=241 THEN 407
408 OUT U,TX'ATTIVA LA TRASMISSIONE DELLA PORTANTE
410 V=INP(L): IF V=241 THEN 410
420 IF V=209 THEN GOSUB 300:GOTO 410'PUNTO NO IAMBIC
425 IF V=177 THEN GOSUB 350'LINEA NO IAMBIC
430 V=INP(L): IF V=145 THEN GOSUB 300: V=INP(L): IF V=145 THEN GOSUB 350: GOTO 430'IAMBIC
440 GOTO 410
Il programma seguente è quello del generatore di frequenza con l'uso di due quarzi.
E' necessario (solo all'accensione) prima di far girare il programma di telegrafia in FM,
attivare la frequenza audio che si desidera usare e poi spegnere l'uscita dando come INPUT
il valore di 0.
A questo punto si può fermare con BREAK e dare RUN per attivare il programma del Tasto
Automatico con manipolazione iambic, o la trasmissione programmata del testo scritto in D$.
1000 INPUT"Frequenza da generare in Hz";F
1005 IF F>0 THEN 1025
1010 IF F=0 THEN OUT 178,236:INPUT"cambio quarzo <> enter";S$
1015 IF S$="" THEN MENU
1020 X=6000000:INPUT"Frequenza in Hz";F:GOTO 1100
1025 X=4915200'QUARZO ORIGINALE
1100 V=INT(X/2/F)
1105 F1=INT(X/(2*V))
1110 IF F1>F THEN V=V+1
1115 PRINT"genero la frequenza di:";INT(X/(2*V))
1120 IF V<2 OR V>16383 THEN BEEP:GOTO 1000
1125 L=V-INT(V/256)*256:H=INT(V/256)+64
1130 FOR G=1 TO 2
1140 OUT 176,195:OUT 180,L:OUT 181,H
1150 NEXT
1160 OUT 178,232'ATTIVA GENERATORE-OUT 178,236 LO SPEGNE
1170 GOTO 1000
NOTA: L'uscita audio si può prelevare facilmente, collegando un condensatore
da 100 nF sul polo caldo (quello che va a massa con una resistenza)
della capsula piezo del computer.
Buoni esperimenti con i vecchi pc, 73 Emilio ik1wjq
Vai a pagina1
Icom T8E - V/UHF tre bande om
I piccoli rtx portatili o tascabili in FM, come in questo caso l'ICOM T8E, non hanno
l'ascolto in AM e tantomeno la CW o l'SSB, tuttavia sulle bande VHF-UHF e oltre,
è facile poter fare la telegrafia modulata, visto l'ampio spazio a disposizione su
queste bande, e la mancanza di qrm per qso alla distanza di alcuni chilometri .
(Un canale in FM banda stretta, occupa circa 12,5 Khz).
Ecco allora un'applicazione con i vecchi e noti computer Olivetti M10 o il corrispondente
americano Tandy 102.
NOTA: Con i piccoli Rtx muniti di vox, non serve l'interfaccia, ma basta posizionare
un microfono volante vicino al diffusore piezoelettrico del pc.
In questo modo il segnale audio è sufficiente ad attivare la trasmissione automatica.
Il programma iniziale serve a trasmettere un messaggio, che viene ripetuto dopo un certo
tempo, il secondo invece permette di usare una chiave a due palette per fare la telegrafia
in FM o AM, usando sempre l'uscita audio del pc.
La risposta del programma è buona, per cui oltre agli esperti se si è alle prime armi, lo
si può usare anche per imparare la manipolazione con la chiave meccanica.
I programmi sono funzionanti al 100%, ma naturalmente si possono ampliare, l'importante
è non rallentare l'esecuzione nella fase di decodifica e trasmissione.
Per semplificare l'esecuzione automatica si decodifica solo i numeri e le lettere oltre
allo spazio tra le varie parole.
Semplice schema dell'interfaccia per la telegrafia in FM con l'ICOM T8E
Audio <-------||-----\/\/\/-----*------------------------------------> Ingresso
2nF 200K | Jack da 2,5 mm mono microfono IC
\ *---------------------> T8E con PTT.
M10 o Tandy 102 / |
\ 2K2 /////
|
(PTT) |
4K7 (C) BC238
DTR (20)<---\/\/\/--*-------*----(B)
| | (E) (*): L'interruttore (bistabile) si usa
RS Chiuso=RX | 4 _|_ | solo per la telegrafia manuale, in
232 \ 1 / \ | modo da commutare velocemente in
Aperto=TX \ 4 | | ricezione senza dover usare i tasti
(*) * 8 | | del computer, che in questo caso si
| | | usa principalmente con la chiave
GND (7)<-----------*-------*-----* meccanica come un tasto automatico
| tradizionale. (Programma da riga 400)
/////
Il seguente programma gira ad elevata velocità, perché usa solo i numeri interi.
Con i valori qui riportati e con il quarzo da 6 Mhz anzichè l'originale da 4,9152 Mhz,
la velocità di trasmissione è di circa 44 PM ossia 44 x 5 = 220 caratteri al minuto,
e si capisce che riducendo i cicli (FOR-NEXT) si può arrivare tranquillamente anche a
60 PM e oltre.
Per ridurre radicalmente la velocità basta eliminare dal programma la riga 0
0 DEFINT A-Z'NUMERI INTERI=BASIC VELOCE
5 OUT 178,236
10 PRINT "CONTROLLO TX ICOM T8E
15 U=178'INDIRIZZO PORTA RS232
20 TX=232-64'COMANDO TRASMISSIONE FM (DTR=1)
25 RX=236'COMANDO RICEZIONE
30 OUT U,RX
35 PRINT"PROVA TRASMISSIONE
40 OUT U,TX
45 FOR G=1 TO 60: NEXT
50 OUT U,RX
55 DIM K$(26)'DATI LETTERE
60 DIM T$(10)'DATI NUMERI
100 DATA ".-","-...","-.-.","-..",".","..-.","--.","....","..",".---","-.-",".-..","--",
"--","-.","---",".--.","--.-",".-.","...","-","..-","...-",".--","-..-","-.--","--.."
105 DATA "-----",".----","..---","...--","....-",".....","-....","--...","---..","----."
110 RESTORE: FOR F=1 TO 26: READ K$(F): NEXT
115 RESTORE 105: FOR F=0 TO 9: READ T$(F): NEXT
120 INPUT D$: IF D$="" THEN 400'SALTA AL TASTO AUTOMATICO
130 FOR W=1 TO 120
135 FOR G=1 TO 100: NEXT G: NEXT W'PAUSA 14 SECONDI CA
140 OUT U,TX+4: FOR G=1 TO 50: NEXT'ATTIVA TRASMISSIONE ICOM
145 PRINT D$
150 FOR D=1 TO LEN(D$)
153 H$=MID$(D$,D,1): IF H$=" " THEN D=D+1: FOR G=1 TO 120:NEXT G:GOTO153
155 K=ASC(H$):IF K>60 THEN 170
160 K=K-48:N$=T$(K): FOR F=1 TO LEN(N$)'ESTRAZIONE E TRASMISSIONE DEL NUMERO
164 IF MID$(N$,F,1)="." THEN GOSUB 300
166 IF MID$(N$,F,1)="-" THEN GOSUB 350
168 GOTO 190
170 K=K-64:N$=K$(K): FOR F=1 TO LEN(N$)'ESTRAZIONE E TRASMISSIONE DELLA LETTERA
175 IF MID$(N$,F,1)="." THEN GOSUB 300
180 IF MID$(N$,F,1)="-" THEN GOSUB 350
190 NEXT F: FOR G=1 TO 90: NEXT G
200 NEXT D: OUT U,RX: GOTO 130'RITORNA A TRASMETTERE IL MESSAGGIO D$
300 OUT U,168: FOR G=1 TO 30: NEXT: OUT U,172: FOR G=1 TO 30: NEXT: RETURN'PUNTO
350 OUT U,168: FOR G=1 TO 90: NEXT: OUT U,172: FOR G=1 TO 30: NEXT: RETURN'LINEA
Collegamenti per il tasto automatico
(Per attivare d5 e d6 vedi l'articolo sul Bus I2C)
Porta 9 pin BCR (M10 - Tandy 102)
Indirizzo=(208)
4n7
*--||---(0 Volt)
| (Linea) ____
D6 (3)<-----*--------------*---------/____|
|
0-Volt (5)<--------------------*----* Manipolatore con chiave a due palette - (Iambic)
| ____
D5 (4)<-----*--------------*---------\____|
| 4n7 (Punto)
*--||---(0 Volt)
400 L=208'INDIRIZZO LETTURA PORTA 9 PIN
405 PRINT"TELEGRAFIA CON CHIAVE IAMBIC IN FM
407 V=INP(L): IF V=241 THEN 407
408 OUT U,TX'ATTIVA LA TRASMISSIONE DELLA PORTANTE
410 V=INP(L): IF V=241 THEN 410
420 IF V=209 THEN GOSUB 300:GOTO 410'PUNTO NO IAMBIC
425 IF V=177 THEN GOSUB 350'LINEA NO IAMBIC
430 V=INP(L): IF V=145 THEN GOSUB 300: V=INP(L): IF V=145 THEN GOSUB 350: GOTO 430'IAMBIC
440 GOTO 410
Il programma seguente è quello del generatore di frequenza con l'uso di due quarzi.
E' necessario (solo all'accensione) prima di far girare il programma di telegrafia in FM,
attivare la frequenza audio che si desidera usare e poi spegnere l'uscita dando come INPUT
il valore di 0.
A questo punto si può fermare con BREAK e dare RUN per attivare il programma del Tasto
Automatico con manipolazione iambic, o la trasmissione programmata del testo scritto in D$.
1000 INPUT"Frequenza da generare in Hz";F
1005 IF F>0 THEN 1025
1010 IF F=0 THEN OUT 178,236:INPUT"cambio quarzo <> enter";S$
1015 IF S$="" THEN MENU
1020 X=6000000:INPUT"Frequenza in Hz";F:GOTO 1100
1025 X=4915200'QUARZO ORIGINALE
1100 V=INT(X/2/F)
1105 F1=INT(X/(2*V))
1110 IF F1>F THEN V=V+1
1115 PRINT"genero la frequenza di:";INT(X/(2*V))
1120 IF V<2 OR V>16383 THEN BEEP:GOTO 1000
1125 L=V-INT(V/256)*256:H=INT(V/256)+64
1130 FOR G=1 TO 2
1140 OUT 176,195:OUT 180,L:OUT 181,H
1150 NEXT
1160 OUT 178,232'ATTIVA GENERATORE-OUT 178,236 LO SPEGNE
1170 GOTO 1000
NOTA: L'uscita audio si può prelevare facilmente, collegando un condensatore
da 100 nF sul polo caldo (quello che va a massa con una resistenza)
della capsula piezo del computer.
Buoni esperimenti con i vecchi pc, 73 Emilio ik1wjq
Vai a pagina1